Расширения конфигураций 1С: учимся перехватывать методы

В этой статье я разберу некоторые механизмы расширений конфигураций 1С. А именно «перехваты» методов модуля объекта и «перехваты» событий формы и элементов формы. Данная статья написана с учебными целями, что бы показать, как при помощи расширений конфигурации можно делать такие доработки, ради которых раньше приходилось снимать конфигурацию с поддержки.

Если кто не знаком с технологией расширений, то основную информацию можно получить из моих видео-уроков.

Семь видео-уроков по работе с расширениями конфигурации!

Все примеры я показываю на демонстрационной конфигурации «Управляемое приложение 1С», априори предполагается, что её нельзя изменять.

Имейте в виду, что перехват событий и методов работает только тогда, когда режим совместимости установлен в «Не использовать» (так было для платформы 8.3.10.1981), по сути это единственное изменения конфигурации  «Управляемое приложение», которое я сделал…

В расширении можно перехватывать типовые процедуры модуля объекта. Имеется возможность сделать три варианта перехвата «типовой» процедуры: «перехватить» событие перед выполнением метода (с помощью аннотации &Перед), «перехватить» событие после выполнения метода (с помощью аннотации &После), а так же выполнить вместо типовой процедуры процедуру расширения (с помощью аннотации &Вместо).

В задачах ниже мы разберем работу «перехватчиков»

Задача: В расширении создадим собственный макет печати документа «Расход товара». И добавим команду на форму расходной накладной «Печать расходной накладной (расширение)» при выполнении которой будет печататься макет из расширения.

Для этого создадим расширение конфигурации «ДляРасходаТовара», заимствуем в это расширение документ «Расход товара», а так же форму.

Скопируем (именно скопируем, а не заимствуем) из расширяемой конфигурации макет «МакетПечати», переименуем его и изменим сам макет, что бы можно было отличать.

Теперь нам нужно скопировать (тоже именно скопировать, а не заимствовать) команду документа «Печать расходной накладной», но группа, в которую входит команда у нас не скопируется, поэтому перед этим необходимо заимствовать группу «Печать»

После этого копируем команду «Печать расходной накладной», и так же переименовываем, и не забудем указать тип параметра команды – ссылку на документ «Расход товаров»

Если мы на этом этапе сохраним расширение и обновим базу данных, то при открытии формы документа, увидим, что команда добавилась.

Но, если мы сейчас попробуем её выполнить, то выйдет обычная печатная форма, не из расширения.

Всё из-за того, что в команде расширения используется метод документа ПечатнаяФорма, в котором и «подтягивается» нужный макет.

Перехватим процедуру ПечатнаяФорма модуля объекта, и переделаем её. Для того что бы понимать, что мы используем табличный документ из расширения, будем, когда вызываем процедуру из команды расширения, передавать в неё структуру с табличным документом. А потом в перехваченной процедуре ПечатнаяФорма в зависимости от типа параметра будем использовать тот или иной макет: если параметр имеет тип ТабличныйДокумент, то будем использовать типовой макет, а если параметр имеет тип Структура, то будем использовать макет из расширения. Для того, что бы перехватить процедуру или функцию в модуле объекта необходимо написать аннотацию &Вместо и после неё в скобочках название перехваченного метода.

Напишем в модуле расширения следующий код:

&Вместо(«ПечатнаяФорма»)
Процедура РТ_ПечатнаяФорма(ТабличныйДокумент)
   
///
КонецПроцедуры // ПечатнаяФорма(ТабличныйДокумент)

Обратите внимание на название метода, он не должен совпадать с основным, поскольку при работе процедуры модулей расширяемой конфигурации и расширений работают в одном контексте.

Теперь скопируем код из процедуры ПечатнаяФорма расширенной конфигурации, и переделаем, как описано выше.

 

&Вместо(«ПечатнаяФорма»)
Процедура РТ_ПечатнаяФорма(ТабличныйДокумент)
    Если
ТипЗнч(ТабличныйДокумент) = тип(«Структура») Тогда
       
ТабличныйДокумент = ТабличныйДокумент.ТабДок;
       
Макет = Документы.РасходТовара.ПолучитьМакет(«РТ_МакетПечати»);
    иначе
   
Макет = Документы.РасходТовара.ПолучитьМакет(«МакетПечати»);
    КонецЕсли;
   
//—————-основной код из расширенной конфигурации—————///
    // Заголовок
   
Область = Макет.ПолучитьОбласть(«Заголовок»);
   
ТабличныйДокумент.Вывести(Область);
   
// Шапка
   
Шапка = Макет.ПолучитьОбласть(«Шапка»);
   
Шапка.Параметры.Заполнить(ЭтотОбъект);
   
ТабличныйДокумент.Вывести(Шапка);
   
// Товары
   
Область = Макет.ПолучитьОбласть(«ТоварыШапка»);
   
ТабличныйДокумент.Вывести(Область);
   
ОбластьТовары = Макет.ПолучитьОбласть(«Товары»);
   
//Обход ТЧ
   
Для каждого ТекСтрокаТовары Из Товары Цикл
       
ОбластьТовары.Параметры.Заполнить(ТекСтрокаТовары);
       
ТабличныйДокумент.Вывести(ОбластьТовары);
    КонецЦикла;
КонецПроцедуры
// ПечатнаяФорма(ТабличныйДокумент)

 

Нам осталось переделать код в команде расширения РТ_ПечатьРасходнойНакладной

&НаСервере
Функция ПечатнаяФорма(ПараметрКоманды)
   
ТабличныйДокумент = Новый ТабличныйДокумент;
   
ТабличныйДокумент.ОтображатьСетку = Ложь;
   
ТабличныйДокумент.Защита = Ложь;
   
ТабличныйДокумент.ТолькоПросмотр = Ложь;
   
ТабличныйДокумент.ОтображатьЗаголовки = Ложь;
   
Сформирован = Ложь;
   
///создаем струкутуру, для передачи в процедуру
   
СтруктураПередачи = Новый Структура(«ТабДок»,ТабличныйДокумент);
    Для каждого
Ссылка Из ПараметрКоманды Цикл
       
Документ = Ссылка.ПолучитьОбъект();
        Если НЕ
Документ.Проведен Тогда
           
Сообщение = Новый СообщениеПользователю();
           
Сообщение.Текст = «Документ не проведен: » + Строка(Документ);
           
Сообщение.КлючДанных = Ссылка;
           
Сообщение.Сообщить();
            Продолжить;
        КонецЕсли;
       
Документ.ПечатнаяФорма(СтруктураПередачи); //передали структуру
       
Сформирован = Истина;
    КонецЦикла;
    Если
Сформирован Тогда
        Возврат
ТабличныйДокумент;
    Иначе
        Возврат Неопределено;
    КонецЕсли;
КонецФункции
&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
   
ТабличныйДокумент = ПечатнаяФорма(ПараметрКоманды);
    Если
ТабличныйДокумент <> Неопределено Тогда
       
ТабличныйДокумент.Показать();
    КонецЕсли;
КонецПроцедуры

Сейчас, после того, как сохраним расширение, то спокойно сможем распечатать макет расширения.

////////////////////

Задача: Перед проведением документа «Расход товара»  будем проверять, внес ли контрагент аванс (должен быть больше суммы продажи), если нет, то не проведем документ.

Для решения этой задачи так же будем использовать аннотацию &Вместо, но в этот раз нам нужно продолжить выполнения основного метода (в нашем случае процедура ОбработкаПроведения).

Напишем в модуле документа «Расход товара» следующий код

&Вместо(«ОбработкаПроведения»)
Процедура РТ_ОбработкаПроведения(Отказ, Режим)
   
Запрос = Новый Запрос;
   
Запрос.Текст = «ВЫБРАТЬ
    |    ВзаиморасчетыОстатки.СуммаОстаток КАК СуммаОстаток
    |ИЗ
    |    РегистрНакопления.Взаиморасчеты.Остатки(
    |            &МоментВремени,
    |            Контрагент = &Контрагент
    |                И Валюта = &Валюта) КАК ВзаиморасчетыОстатки»;
   
Запрос.УстановитьПараметр(«МоментВремени»,?(Режим = РежимПроведенияДокумента.Оперативный,ТекущаяДата(),МоментВремени()));
   
Запрос.УстановитьПараметр(«Контрагент», Ссылка.Покупатель);
   
Запрос.УстановитьПараметр(«Валюта»,Ссылка.Валюта);
   
//устанавливаем блокировки
   
Блокировка = Новый БлокировкаДанных;
   
ЭлБлокировки = Блокировка.Добавить(«РегистрНакопления.Взаиморасчеты»);
   
ЭлБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
   
ЭлБлокировки.УстановитьЗначение(«Контрагент»,Ссылка.Покупатель);
   
ЭлБлокировки.УстановитьЗначение(«Валюта»,Ссылка.Валюта);
   
Блокировка.Заблокировать();
   
///
   
Результат = Запрос.Выполнить();
   
Выборка = Результат.Выбрать();
   
Выборка.Следующий();
    Если
Ссылка.Товары.Итог(«Сумма») > Выборка.СуммаОстаток Тогда
       
СуммаНеДобора = Ссылка.Товары.Итог(«Сумма») + Выборка.СуммаОстаток;
       
Сообщение = Новый СообщениеПользователю;
       
Сообщение.Текст = «Авансов у покупателя недостаточно!» + Символы.ПС + «Не хватает » + СуммаНеДобора ;
       
Сообщение.Поле = «Покупатель»;
       
Сообщение.УстановитьДанные(ЭтотОбъект);
       
Сообщение.Сообщить();
       
Отказ = Истина;
    КонецЕсли;
   
ПродолжитьВызов(Отказ,Режим);
КонецПроцедуры

В этом коде мы получаем остаток по регистру взаиморасчетов по покупателю в разрезе валюты. И если в документе сумма всех товаров больше чем остаток по взаиморасчету, то присваиваем параметру Отказ значение истина и выводим сообщение. А в конце процедуры вызываем метод ПродолжитьВызов с теми же параметрами, что и у нашей процедуры.  Подробно про метод ПродолжитьВызов можно прочитать в синтаксис-помощнике, отмечу только: что бы не путаться, лучше называть параметры в методе-перехватчике, так же как и в методе расширенной конфигурации.

Посмотрим, как сработает наш перехват события

Кроме того, что мы можем написать метод, который сработает взамен метода расширенной конфигурации, мы можем написать процедуру (функцию), которая выполниться перед или после какой-нибудь «типового» метода модуля объекта. Для этого нужно использовать аннотации &Перед и &После.

Решим следующую задачу: в конфигурации «Управляемое приложение 1С» на основании контрагента нужно можно создать документ «Расход товара», в котором заполнится Контрагент и поле «Вид цены». Допустим нам не нужно автоматическое заполнение вида цены, поэтому мы перехватим событие после выполнения процедуры ОбработкаЗаполнения в модуле документа «Расход товара», где присвоим полю Вид цены пустую ссылку. Получиться вот такой код

&После(«ОбработкаЗаполнения»)
Процедура РТ_ОбработкаЗаполнения(ДанныеЗаполнения, СтандартнаяОбработка)
    Если
ТипЗнч(ДанныеЗаполнения) = Тип(«СправочникСсылка.Контрагенты») Тогда
       
ВидЦен = Справочники.ВидыЦен.ПустаяСсылка();
    КонецЕсли;
КонецПроцедуры

Если мы сейчас создадим на основании контрагента документ «Продажи», то поле «Вид Цены» будет пустое

Теперь перейдем к формам.

Платформа позволяет перехватывать в расширении события формы и элементов формы. Так же как и для модуля объекта существует три варианта перехвата события: перед событием, после события и вместо события. Но задаются они по другому: по средством указания типа вызова при создании обработчика

Разберем работу перехвата событий форм на ряде примеров.

Задача:  В документе «Расход товара» после выбора контрагента в окно «Обоснование отгрузки» будем записывать информацию из реквизита контрагента «Дополнительная информация».

Для этого перехватим событие после изменения поля «Покупатель».  Зайдем в палитру свойств поля «Покупатель» формы документа «Расход товара» нашего расширения. И нажмем на пиктограмму «Лупа» рядом с событием «При изменении», после этого выйдет форма, где по мимо знакомых вариантов клиент, сервер и т.д., появятся варианты вызова события: перед, после и вместо.

Выберем на клиенте и после.

После выбора в палитре свойств рядом с созданным событием появилась соответствующая пиктограмма.

В модуле формы обработка создалась. Напишем следующий код.

&НаСервереБезКонтекста
Функция ПолучитьДопИнформацию(Контрагент)
    Возврат
Контрагент.ДополнительнаяИнформация;
КонецФункции
&НаКлиенте
Процедура РТ_ПокупательПриИзмененииПосле(Элемент)
   
Объект.ОбоснованиеОтгрузки = ПолучитьДопИнформацию(Объект.Покупатель);
КонецПроцедуры

Теперь, если мы выберем контрагента, то заполнится информация в поле документа «Обоснование отгрузки»

И последняя задача будет немного поинтереснее: в документе «Расход товара» в табличной части Товары сделаем возможность выбора только номенклатуры с видом Товар. В демонстрационной конфигурации есть товары с видом услуга. Они показаны на этом рисунке

Доработаем расширение конфигурации таким образом, что бы в форме документа «Расход товара» при выборе товара в табличной части, выходила форма выбора справочника «Товары» с отбором по виду товара. Для этого я заимствую форму выбора справочника товары в мое расширение.

И у этой формы создам обработчик события ПриСозданииНаСервере, который будет выполняться вместо типового.

Почему вместо типового? Потому что типового обработчика события ПриСозданииНаСервер формы выбора справочника Товары нет, и я решил сделать вместо. Хотя можно сделать после.

Теперь напишем код, в котором будем устанавливать отбор на динамический список «Список»  формы выбора.

&НаСервере
Процедура РТ_ПриСозданииНаСервереВместо(Отказ, СтандартнаяОбработка)
    Если
Параметры.Свойство(«Вид») Тогда
       
Отбор = Список.Отбор;
       
НовыйЭлОтбора = Отбор.Элементы.Добавить(Тип(«ЭлементОтбораКомпоновкиДанных»));
       
НовыйЭлОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных(«Вид»);
       
НовыйЭлОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
       
НовыйЭлОтбора.ПравоеЗначение = Параметры.Вид;
    КонецЕсли;
КонецПроцедуры

Все. С формой выбора мы покончили, и можем начать работать с формой документа «Расход товара». Первым делом, создадим событие НачалоВыбора поля Товар таблицы Товары, которое будем выполнять в место типового.

В этом обработчике мы напишем код, в результате которого будет открываться формы выбора справочника товары, и при открытии в эту форму будем передавать в качестве параметра вид товара – товар.

&НаКлиенте
Процедура РТ_ТоварыТоварНачалоВыбораВместо(Элемент, ДанныеВыбора, СтандартнаяОбработка)
   
//отменим стандартный вызов
   
СтандартнаяОбработка = Ложь;
   
//передадим параметры на форму
   
ПараметрыОткрытия = Новый Структура;
   
ПараметрыОткрытия.Вставить(«Вид»,ПредопределенноеЗначение(«Перечисление.ВидыТоваров.Товар»));
   
//опишем оповещение о закрытии
   
ОповещениеОЗакрытииВыбораТовара = Новый ОписаниеОповещения(«ВыполнитьПослеЗакрытияВыбораТовара»,ЭтотОбъект);
   
ОткрытьФорму(«Справочник.Товары.ФормаВыбора»,ПараметрыОткрытия
                ,ЭтаФорма
                ,УникальныйИдентификатор
                ,,,
               
ОповещениеОЗакрытииВыбораТовара,);
КонецПроцедуры

Не забудем написать процедуру, которая должна сработать после закрытия формы выбора

&НаКлиенте
Процедура ВыполнитьПослеЗакрытияВыбораТовара(РезультатЗакрытия,ДополнительныеПараметры) Экспорт
    Если Не
ЗначениеЗаполнено(РезультатЗакрытия) Тогда
        Возврат;
    КонецЕсли;
   
Идентификатор = Элементы.Товары.ТекущаяСтрока;
   
СтрТовара = Объект.Товары.НайтиПоИдентификатору(Идентификатор);
   
СтрТовара.Товар = РезультатЗакрытия;
КонецПроцедуры

Теперь при выборе товаров из документа «Расход товара» каталог «Услуги» будет пуст.

Но, заметьте, можно будет подобрать услугу, вводя вручную её название в поле товар.

Что бы такого не было, мы перехватим событие формы АвтоПодбор, наше событие будет выполняться вместо события расширенной конфигурации.

В этом обработчике будем накладывать отбор в параметрах получения данных

&НаКлиенте
Процедура РТ_ТоварыТоварАвтоПодборВместо(Элемент, Текст, ДанныеВыбора, ПараметрыПолученияДанных, Ожидание, СтандартнаяОбработка)
   
Отбор = ПараметрыПолученияДанных.Отбор;
   
Отбор.Вставить(«Вид»,ПредопределенноеЗначение(«Перечисление.ВидыТоваров.Товар»))
КонецПроцедуры

Теперь при подборе с клавиатуры услуги не будут выходить.

На этом всё. Надеюсь, эта статья принесла Вам пользу, и помогла понять, как можно перехватывать «Типовые» события при помощи расширений конфигурации.

Книга «Азбука расширений конфигураций 1С»

Азбука расширений конфигураций 1С

 

В книге «Азбука расширений конфигураций 1С» в доступной форме подробно шаг за шагом даются основы работы с этим механизмом расширений конфигураций 1С.

После её прочтения Вы сможете самостоятельно использовать технологию расширения конфигураций 1С в своей работе. Вы окажите своим клиентам более высокий уровень сервис и выведете свой профессионализм на новый уровень!

 

 

Книга «Программировать в 1С за 11 шагов»

 

Изучайте программирование в 1С в месте с моей книги «Программировать в 1С за 11 шагов»

  1. Книга написана понятным и простым языком — для новичка.
  2. Научитесь понимать архитектуру 1С;
  3. Станете писать код на языке 1С;
  4. Освоите основные приемы программирования;
  5. Закрепите полученные знания при помощи задачника;

 

Книга «Основы разработки в 1С: Такси»

 

Отличное пособие по разработке в управляемом приложении 1С, как для начинающих разработчиков, так и для опытных программистов.

  1. Очень доступный и понятный язык изложения
  2. Книга посылается на электронную почту в формате PDF. Можно открыть на любом устройстве!
  3. Поймете идеологию управляемого приложения 1С
  4. Узнаете, как разрабатывать управляемое приложение;
  5. Научитесь разрабатывать управляемые формы 1С;
  6. Сможете работать с основными и нужными элементами управляемых форм
  7. Программирование под управляемым приложением станет понятным

Промо-код на скидку в 15% — 48PVXHeYu


Если Вам помог этот урок решить какую-нибудь проблему, понравился или оказался полезен, то Вы можете поддержать мой проект, перечислив любую сумму:

можно оплатить вручную:

Яндекс.Деньги — 410012882996301
Web Money — R955262494655

Вступайте в мои группы:

Вконтакте: https://vk.com/1c_prosto
Фейсбуке: https://www.facebook.com/groups/922972144448119/
ОК: http://ok.ru/group/52970839015518
Твиттер: https://twitter.com/signum2009

Добавить комментарий

Ваш e-mail не будет опубликован. Обязательные поля помечены *

пять × четыре =